

    

        faktory_worker

        v1.9.10



    


  

    Table of contents

    
      



      	Faktory Worker


      	Configuration


      	Logging


      	Sandbox Testing


      	Mutate API





        	
          Modules
          


      	FaktoryWorker


      	FaktoryWorker.Batch


      	FaktoryWorker.Job


      	FaktoryWorker.Sandbox


      	FaktoryWorker.Testing





        



      

    

  

    Faktory Worker

A worker client for Faktory.
Documentation
Faktory Worker documentation is available at https://hexdocs.pm/faktory_worker.
Getting up and running
To get started with Faktory Worker first add the dependency to your mix.exs file.
defp deps do
  [
    {:faktory_worker, "~> 1.9.8"}
  ]
end
Faktory Worker can then be configured to start as part of your application by adding it to the Application.start/2 function.
defmodule MyApp.Application do
  use Application

  def start(_, _) do
    children = [
      FaktoryWorker
    ]

    Supervisor.start_link(children,
      strategy: :one_for_one,
      name: MyApp.Supervisor
    )
  end
end
Make sure you have configured your application to start in your mix.exs file.
def application do
  [
    mod: {MyApp.Application, []}
  ]
end
This will start Faktory Worker using the default configuration. For details on how to configure Faktory Worker
see the FaktoryWorker documentation.
Next you can create a worker to handle job processing.
defmodule MyApp.SomeWorker do
  use FaktoryWorker.Job

  def perform(job_data) do
    do_some_work(job_data)
  end
end
Now you can start sending jobs to faktory and they will be automatically picked up by the worker.
:ok = MyApp.SomeWorker.perform_async("hey there!")
Important! Since version 1.6.1 Broadway was removed from dependencies and response from perfomr_async is tuple {:ok, job_meta} with meta information about scheduled job.
{:ok, job_meta} = MyApp.SomeWorker.perform_async("hey there!")
Sending multiple job arguments
It's possible to send more than one argument to Faktory by passing a list of data to perform_async/1. Picking up from the example in the Getting up and running section we can modify our worker by adding another perform function with an arity that matches the number of job arguments we expect to send to Faktory.
defmodule MyApp.SomeWorker do
  use FaktoryWorker.Job

  ...

  def perform(arg1, arg2) do
    do_some_work(arg1, arg2)
  end
end
With this new function in place you can now send multiple job arguments to Faktory.
:ok = MyApp.SomeWorker.perform_async(["arg 1", "arg 2"])
Configuration
The full list of configuration options are available in the Configuration documentation.
Logging
By default Faktory Worker will not output any log messages but instead emit events using the Telemetry library.
To enable the built in logging you will need to attach the default Telemetry handler provided by FaktoryWorker. The ideal place to do this is in your Application.start/2 callback.
defmodule MyApp.Application do
  use Application

  def start(_, _) do
    FaktoryWorker.attach_default_telemetry_handler()

    ...
  end
end
With this in place Faktory Worker will now output log messages for each of the events emitted.
For a full list of Faktory Worker events or for details on handling these events see the Logging documentation.
Contributing
We always appreciate contributions whether they are testing, reporting issues, feedback or submitting PRs. If you would like to work on Faktory Worker please follow the Developing section for details on how to get setup for developing and running the test suite.
Developing
Faktory Worker includes a docker compose file that provisions all of the Faktory instances required to run the test suite.
If you have docker compose installed you can run the up command from the Faktory Worker directory to start everything required.
$ docker compose up -d
Creating faktory_worker_test          ... done
Creating faktory_worker_test_tls      ... done
Creating faktory_worker_password_test ... done

Faktory have free open-source solution and enterprise edition.
If you don't have enterprise license then tests will fail on enterprise features (batching operations etc). In this case you can exclude them by tag :enterprise
mix test --exclude enterprise

If you are enterprise user all tests should pass
mix test



  

    Faktory Worker Configuration

Available Configuration
Faktory Worker offers a range configuration options that are passed into the FaktoryWorker module directly when defining it as part of a supervision tree. All of these options are optional and have default values defined.
Configuration can be specified in the supervision tree using a two element tuple.
defmodule MyApp.Application do
  use Application

  def start(_, _) do
    children = [
      {FaktoryWorker, [name: :faktory_test]}
    ]

    ...
  end
end
Below is the full structure of available options and a definition for each one.
[
  name: atom(),
  retry_on_error: boolean(),
  connection: [
    host: String.t(),
    port: pos_integer(),
    password: String.t(),
    use_tls: boolean(),
    labels: list(String.t())
  ],
  pool: [
    size: pos_integer(),
    buffer_size: pos_integer() | :infinity
  ],
  worker_pool: [
    size: pos_integer(),
    disable_fetch: boolean(),
    queues: [
      list(String.t() | {String.t(), keyword()})
    ]
  ]
]
Option Definitions
	name (default: FaktoryWorker) - The name to use for this instance. This is useful if you want to run more than one instance of Faktory Worker. When using this make sure the workers are configured to use the correct instance (see Worker Configuration below).

	retry_on_error (default: false) - When disabled, only consider jobs that raise as failed and retry them. When enabled, also consider the return value from perform callbacks when determining whether or not to retry a job. A return of :error or {:error, term()} will retry the job.

	connection - A list of options to configure the connection to Faktory.
	host (default: "localhost") - The host name used to connect to Faktory.
	port (default: 7419) - The tcp port used to connect to Faktory.
	password (default: nil) - The password used to authenticate with Faktory.
	use_tls (default: false) - A boolean flag that indicates whether Faktory Worker should connect using a TLS connection.
	labels (default: ["elixir-#{System.version()}"]) - A list of strings added to the worker processes.


	pool - A list of options to configure the pool of Faktory connections used for sending jobs to Faktory.
	size (default: 10) - The number of connections to open to Faktory.
	buffer_size (default: :infinity) - The number of jobs that can be stored in memory whilst waiting for an available connection from the pool. Note that this defaults to :infinity to prevent losing jobs during high load scenarios. This could potentially lead to increased memory consumption if there is low throughput to Faktory.


	worker_pool - A list of options to configure the Faktory workers.
	size (default: 10) - The number of worker connections to open to Faktory.
	disable_fetch (default: false) - A boolean flag used to disable fetching on each of the workers. This is useful if you want to prevent the workers from fetching new jobs without having to remove the queues config.
	queues (default: ["default"]) - A list of queues that the workers should fetch jobs from. See the Configuring Queues section below for more details.



Configuring Queues
Queues are configured by specifying a list of strings or tuples.
queues: ["queue_name", {"another_queue", opts}]
The queue name must match the name of the queue in Faktory. Using the tuple definition allows a list of options to be specified when fetching jobs from that queue.
The available options are.
[
  max_concurrency: pos_integer() | :infinity
]
Option Definitions
	max_concurrency (default: :infinity) - The maximum number of jobs that should be fetched and processed from this queue in parallel.

Worker Configuration
Workers can be configured with queue specific options that are used by Faktory Worker when sending jobs to Faktory. All of these options are optional and have default values.
Options are defined when using FaktoryWorker.Job.
use FaktoryWorker.Job, opts
Below is the full structure of available options and a definition for each one.
[
  queue: String.t(),
  jobtype: String.t(),
  at: DateTime.t(),
  retry: pos_integer(),
  reserve_for: pos_integer(),
  custom: map(),
  faktory_name: atom()
]
Option Definitions
	queue (default: "default") - The name of the queue in Faktory to send jobs to.
	jobtype (default: __MODULE__) - The type of job to send. This is used to determine how to process a job when fetched from Faktory.
	at (relies on Faktory default) - The date and time Faktory should run the job.
	retry (relies on Faktory default) - The number of times the job should retry if it fails.
	reserve_for (relies on Faktory default) -The number of seconds the job is reserved for in Faktory before it is considered failed.
	custom (relies on Faktory default) - A map of values to be included with the job when it is sent to Faktory.
	faktory_name (default: FaktoryWorker) - The name of the Faktory instance to use when sending the job to Faktory.



  

    Faktory Worker Logging

Faktory Worker uses the Telemetry library to emit events that can be handled by either Faktory Worker or the consuming application. This provides the flexibility for the consumer of Faktory Worker to choose how logging should behave.
By default Faktory Worker will not output any log messages. Logging needs to be explicitly enabled by calling the FaktoryWorker.attach_default_telemetry_handler/0 function.
Events can also be handled in the consuming application by manually attaching to Telemetry specifying the list of Faktory Worker events to handle. For instructions on creating a custom event handler see the Telemetry README.
All Faktory Worker events are prefixed with :faktory_worker and have a single event name. For example the full event name for the push event is [:faktory_worker, :push].
The measurements data included for all events will be a map containing a status field that will indicate the outcome of the event being emitted. The available outcomes are listed individually below for each type of event.
Push Event
Event Name: [:faktory_worker, :push].
The push event is emitted when a job has been sent to Faktory. The status of this event indicates whether the job was sent successfully.
The available status outcomes are.
	:ok - The job was successfully sent to Faktory.
	{:error, :not_unique} - The job was not sent to Faktory because another job with the same uniqueness already exists.

The metadata supplied with this event is a map containing the Faktory job arguments.
Fetch Event
Event Name: [:faktory_worker, :fetch].
The fetch event is emitted when attempting to fetch a job from Faktory. The status of this event indicates whether the fetch request was sent successfully.
The available status outcomes are.
	{:error, reason} - The request to fetch from Faktory failed. The reason will be any valid term indicating the reason the fetch failed.

The metadata supplied with this event is a map containing the following fields.
	wid - A worker identifier that can be used to identify which worker emitted this event.

Ack Event
Event Name: [:faktory_worker, :ack].
The ack event is emitted when reporting the success or failure of a processed job to Faktory. The status of this event indicates the outcome of processing the job.
The available status outcomes are.
	:ok - The job completed successfully and has been reported to Faktory.
	:error - The job failed to complete and has been reported to Faktory with details about the failure.

The metadata supplied with this event is a map containing the Faktory job arguments.
Failed Ack Event
Event Name: [:faktory_worker, :failed_ack].
The failed ack event is emitted when Faktory Worker was unable to report the outcome of processing a job to Faktory. The status of this event indicates the outcome of the processed job that failed to reach Faktory.
The available status outcomes are.
	:ok - The job completed successfully.
	:error - The job failed to complete.

The metadata supplied with this event is a map containing the Faktory job arguments.
Beat Event
Event Name: [:faktory_worker, :beat].
The beat event is emitted every time a worker has attempted to send a heartbeat message to Faktory. The status of this event indicates whether the heartbeat message was successfully received by Faktory.
The available status outcomes are.
	:ok - The heartbeat message was successfully received by Faktory.
	:error - The heartbeat message failed to reach Faktory.

The metadata supplied with this event is a map containing the following fields.
	wid - A worker identifier that can be used to identify which worker emitted this event.
	prev_status - The status that was emitted on the previous beat event. This is useful for tracking when the status has changed between heartbeats.

Job Timeout Event
Event Name: [:faktory_worker, :job_timeout].
The job timeout event is emitted 20 seconds prior to a job's reservation deadline. This 20-second window allows the job to be terminated before Faktory can expire and retry the job on the server.
The status status provided for this event will always be {:error, :job_timeout}.
The metadata supplied with this event is a map containing the job's ID, arguments, and type.


  

    Sandbox Testing

When testing your application, you may not want to actually push/pull jobs to
Faktory, but instead rely on asserting that jobs would be enqueued as you
expect. Enabling sandbox mode will accomodate this; when sandbox mode is active,
the following changes are made:
	no connection will be made to Faktory (you don't even need a Faktory server running!)
	jobs enqueued (with perform_async/2) will never be run
	jobs enqueued will be recorded, and can be viewed using FaktoryWorker.Sandbox

To enable sandbox mode, set :sandbox to true:
# config/test.exs

config :my_app, FaktoryWorker, sandbox: true
# lib/my_app/application.ex

defmodule MyApp.Application do
  @moduledoc false

  use Application

  def start(_type, _args) do
    children = [
      {FaktoryWorker, Application.get_env(:my_app, FaktoryWorker)}
    ]

    opts = [name: MyApp.Supervisor, strategy: :one_for_one]
    Supervisor.start_link(children, opts)
  end
end
You can verify that sandbox mode is enabled with FaktoryWorker.Sandbox.active?/0.
Writing Tests
To aid in tests that rely on jobs being enqueued, as well as tests for job modules
themselves, you can use the helpers in FaktoryWorker.Testing. Below is a simple
test for a module that enqueues a job:
defmodule MyApp.QueueTest do
  use ExUnit.Case

  import FaktoryWorker.Testing

  setup :reset_queues

  test "perform/1" do
    MyApp.Job.perform_async("hello, world!")
    assert_enqueued MyApp.Job, args: ["hello, world!"]
    refute_enqueued MyApp.Job, args: ["goodbye!"]
  end

  test "multiple enqueues" do
    for _ <- 1..10 do
      MyApp.Job.perform_async("brrrrr")
    end

    assert_enqueued MyApp.Job, count: 10
  end

  test "perform/2" do
    MyApp.Job.perform_async(["foo", "bar"])
    assert_enqueued MyApp.Job, args: ["foo", "bar"]
  end

  test "with opts" do
    MyApp.Job.perform_async("howdy", reserve_for: 1_500)
    assert_enqueued MyApp.Job, opts: [reserve_for: 1_500]

    # these would work too!
    # assert_enqueued MyApp.Job, args: ["howdy"]
    # assert_enqueued MyApp.Job, args: ["howdy"], opts: [reserve_for: 1_500]
  end
end
Here's a simple example test for a job module itself:
defmodule MyApp.JobTest do
  use ExUnit.Case

  import FaktoryWorker.Testing

  test "handles no arguments" do
    assert perform_job(MyApp.Job) == :ok
  end

  test "handles strings" do
    assert perform_job(MyApp.Job, "foo") == :ok
  end

  test "handles maps" do
    assert perform_job(MyApp.Job, %{id: 1}) == {:ok, "cool, a map!"}
  end

  test "handles structs" do
    # structs are serialized and passed to `perform` as bare maps
    assert perform_job(MyApp.Job, %MyApp.User{id: 1}) == {:ok, "cool, a map!"}
  end

  test "doesn't handle numbers" do
    assert perform_job(MyApp.Job, 1_234) == {:error, "boo, no numbers!"}
  end

  test "gracefully handles raises" do
    assert perform_job(MyApp.Job, "I'll cause a raise!") == {:error, "raise reason"}
  end
end
When you can, prefer to use perform_job/3 instead of calling perform directly, as
it will ensure that the code under test is run in the same way that it will eventually
be at runtime.


  

    Mutate API

From the Faktory documentation:
It's inevitable: you will have cases where you enqueue bad data or have jobs
which need pruning, migration or some other rare use case. For this, Faktory
provides low-level data management APIs so you can script certain repairs or
migrations.

Please be warned: MUTATE commands can be slow and/or resource intensive.
They should not be used as part of your application logic.

Usage (Experimental)
Support for the Mutate API is currently very basic. At some point in the future,
this may be enhanced with a first-class Elixir API, but for now calls must be
made manually:
args = %{
  cmd: "kill",
  target: "default",
  filter: %{jobtype: "MyApp.Job"}
}

FaktoryWorker.send_command({:mutate, args})
See here for the
full MUTATE argument reference.

The FaktoryWorker module provides everything required to setup workers for sending and fetching jobs.
It is expected that FaktoryWorker will be configured and started as part of a supervision tree. Multiple instances of
FaktoryWorker can be configured by providing the :name  option which must be unique.
This module can either be configured using all default options.
children = [
  FaktoryWorker
]
Or by using the two element tuple format accepting a list of options as the second element.
children = [
  {FaktoryWorker, [name: :faktory_test, ...]}
]
For a full list of configuration options see the Configuration documentation.

      send_command_opt()



        
          
        

    

  


  

      

          @type send_command_opt() :: {:faktory_name, module()} | {:timeout, pos_integer()}

          @spec attach_default_telemetry_handler() :: :ok | {:error, :already_exists}


      


Attaches the default telemetry handler provided by FaktoryWorker.
This function attaches the default telemetry handler provided by FaktoryWorker that
outputs log messages for each of the events emitted by FaktoryWorker.
For a full list of events see the Logging documentation.

          @spec send_command(command(), [send_command_opt()]) ::
  FaktoryWorker.Connection.response() | {:error, :timeout}


      


Send a command to the Faktory server.
In most cases, FaktoryWorker handles sending commands on your behalf.
However, there are some APIs (such as Enterprise Batches and Tracking)
where it's useful to send a command directly.
The full list of supported commands is available in
FaktoryWorker.Protocol.protocol_command(). It is left to the caller to
verify that command arguments are valid.
Options
	faktory_name the Faktory instance to use (default: FaktoryWorker)
	timeout how long to wait for a response, in ms (default: 5000)

Supports Faktory Batch operations
Batch support is a
Faktory Enterprise feature. It allows jobs to pushed as part of a batch. When
all jobs in a batch have completed, Faktory will queue a callback job. This
allows building complex job workflows with dependencies.
Creating a batch
A batch is created using new!/1 and must provide a description and declare
one of the success or complete callbacks. The new!/1 function returns the
batch ID (or bid) which identifies the batch for future commands.
Once created, jobs can be pushed to the batch by providing the bid in the
custom payload. These jobs must be pushed synchronously.
alias FaktoryWorker.Batch

{:ok, bid} = Batch.new!(on_success: {MyApp.EmailReportJob, [], []})
MyApp.Job.perform_async([1, 2], custom: %{"bid" => bid})
MyApp.Job.perform_async([3, 4], custom: %{"bid" => bid})
MyApp.Job.perform_async([5, 6], custom: %{"bid" => bid})
Batch.commit(bid)
Opening a batch
In order to open a batch, you must know the batch ID. Since FaktoryWorker
doesn't currently pass the job itself as a parameter to perform functions,
you must explicitly pass it as an argument in order to open the batch as part
of a job.
defmodule MyApp.Job do
  use FaktoryWorker.Job

  def perform(arg1, arg2, bid) do
    Batch.open(bid)

    MyApp.OtherJob.perform_async([1, 2], custom: %{"bid" => bid})

    Batch.commit(bid)
  end
end

Commits the batch identified by bid
Faktory will begin scheduling jobs that are part of the batch before the batch

          @spec new!(Keyword.t()) :: {:ok, bid()} | {:error, any()}


      


Creates a new Faktory batch
Returns the batch ID (bid) which needs to be passed in the :custom
parameters of every job that should be part of this batch as well as to commit
the batch.
Opts
Batch jobs must define a success or complete callback (or both). These
callbacks are passed as tuples to the :on_success and :on_complete opts.
They are defined as a tuple consisting of {mod, args, opts} where mod is a
module with a perform function that corresponds in arity to the length of args.
Any opts that can be passed to perform_async/2 can be provided as opts
to the callback except for :faktory_worker.
If neither callback is provided, an error will be raised.
:on_success
See above.
:on_complete
See above.
:description
The description, if provided, is shown in Faktory's Web UI on the batch
listing tab.
:parent_bid
The parent batch ID--only used if you are creating a child batch.
:faktory_name
The name of the FaktoryWorker instance (determines which connection pool
will be used).
:timeout
How long to wait for a response, in ms.

Opens the batch identified by bid
An existing batch needs to be re-opened in order to add more jobs to it or to
add a child batch.
After opening the batch, it must be committed again using commit/2.

Gets the status of a batch
Returns a map representing the status

The FaktoryWorker.Job module is used to perform jobs in the background by sending to and fetching from Faktory.
To build a worker you must use the job module within a module in your application.
defmodule MyApp.SomeWorker do
  use FaktoryWorker.Job
end
This will bring in all of the functionality required to perform jobs via Faktory. The MyApp.SomeWorker will now
have a perform_async/2 function available for sending jobs to Faktory. Before this function can be called, a
perform function must be defined. This function must accept the same number of arguments that are
being sent to Faktory via the perform_async/2 function.
defmodule MyApp.SomeWorker do
  use FaktoryWorker.Job

  def perform(job_arg) do
    do_some_work(job_arg)
  end
end
With this in place it is now possible to send work to Faktory and the MyApp.SomeWorker will fetch the job and call
the perform/1 function with the same job arguments that we sent.
> MyApp.SomeWorker.perform_async("job arg")
:ok
It is also possible to send multiple arguments for a single job by passing in a list of values to the perform_async/2
function.
> MyApp.SomeWorker.perform_async(["job arg1", "job arg2"])
:ok
In order for the job to be performed correctly, a perform/2 function needs to be defined within the MyApp.SomeWorker
module.
defmodule MyApp.SomeWorker do
  use FaktoryWorker.Job

  def perform(job_arg1, job_arg2) do
    do_some_work(job_arg1, job_arg2)
  end
end
When defining perform functions, they must always accept one argument for each item in the list of values passed into
perform_async/2.
Retrying jobs on failure
When a job fails, the Faktory server can enqueue it again to be retried. By default, a job is only considered
to have failed when it raises an exception.
def perform do
  raise "retry me!"
end
If you would like to consider the return value from perform and retry when an error is returned, you may enable
the :retry_on_error config option.
# config.exs
config :my_app, FaktoryWorker, retry_on_error: true

# job.ex
def perform do
  case MyWorker.do_work() do
    # returning `:error` or `{:error, term()}` will retry the job
    # when `:retry_on_error` is set to `true`
    :error -> :error
    {:error, reason} -> {:error, reason}
    
    # raising will still retry the job, as well
    {:error, "fatal"} -> raise("oh no!")

    # returning anything else will be considered a success
    :ok -> :ok
    _ -> :something_else
  end
end
Synchronous job pushing
Previous version used Broadway to send jobs and :skip_pipeline parameter was used to do it synchronously.
:skip_pipeline is not supported anymore.
Since Batch operations is a feature of Faktory Enterprise this library now sends any single job synchronously
and makes HTTP call to faktory server (see FaktoryWorker.Batch).
Worker Configuration
A list of options can be specified when using the the FaktoryWorker.Job module. These options will be used when sending
jobs to faktory and will apply to all jobs sent with the perform_async/2 function.
For a full list of configuration options see the Worker Configuration documentation.
Overriding Worker Configuration
The perform_async/2 function accepts a keyword list as its second argument. This list has the same options
available that the FaktoryWorker.Job module accepts. Any options passed into this function override the options
that have been set on the worker module.
For a full list of configuration options see the Worker Configuration documentation.
Data Serialization
Faktory expects all values to be serialized in JSON format. FaktoryWorker uses Jason for serialization. This
means only values that implement the Jason.Encoder protocol are valid when calling the perform_async/2 function.

When started with sandbox mode enabled, FaktoryWorker won't connect
to a running Faktory instance or perform queued jobs, but will instead
record all jobs enqueued locally.
In general, this mode should only be used during testing. See
Sandbox Testing to read more.

      active?()



        
          
        

    

  


  

      

          @spec active?() :: boolean()


      


Returns true if sandbox mode is enabled.

  



  
    
      
    
    
      all_jobs()



        
          
        

    

  


  

      

          @spec all_jobs() :: [job()]


      


Returns a list of all locally enqueued jobs across all job modules, in
the order that they were enqueued. If you only want to retrieve jobs
enqueued for a specific job module, use all_jobs/1 instead.

  



  
    
      
    
    
      all_jobs(worker_mod)



        
          
        

    

  


  

      

          @spec all_jobs(module()) :: [job()]


      


Returns a list of all locally enqueued jobs for the given job module,
in the order that they were enqueued. If you want to retrieve a list of
all jobs across all job modules, use all_jobs/0 instead.

  



  
    
      
    
    
      batch_id()



        
          
        

    

  


  


  



  
    
      
    
    
      batch_status()



        
          
        

    

  


  


  



  
    
      
    
    
      child_spec(init_arg)



        
          
        

    

  


  

Returns a specification to start this module under a supervisor.
See Supervisor.

  



  
    
      
    
    
      reset()



        
          
        

    

  


  

      

          @spec reset() :: :ok


      


Clear the queue history for all job modules.

  



  
    
      
    
    
      reset(worker_mod)



        
          
        

    

  


  

      

          @spec reset(module()) :: :ok


      


Clear the queue history for the given job module.

  


        

      


  

    
FaktoryWorker.Testing 
    



      
Test utilities for asserting and refuting whether jobs are enqueued,
as well as performing jobs as they will be performed when pulled off
the queue at runtime.
See Sandbox Testing to read more.

      


      
        Summary


  
    Functions
  


    
      
        assert_enqueued(worker_mod, filters \\ [])

      


        Assert that a job was enqueued for the given job module, optionally matching
a set of argument/option filters. By default, this assertion will fail if more
than one matching job is found. If you want to assert that multiple matching
jobs are enqueued, you can use the :count option. If you want the assertion
to pass if at least one matching job is enqueued, pass count: :any (this
should generally be discouraged in favor of a specific count, to help catch
accidental duplicate enqueues).



    


    
      
        describe_jobs(jobs)

      


    


    
      
        perform_job(worker_mod, arg_or_args \\ [], opts \\ [])

      


        Perform the job in the same way that it will be performed when pulled
from the queue at runtime. Specifically, this means



    


    
      
        refute_enqueued(worker_mod, filters \\ [])

      


        Assert that a job was not enqueued for the given job module, optionally
specifying a set of argument/option filters.



    


    
      
        reset_queues(context \\ %{})

      


        Resets the queue history for all job modules.



    





      


      
        Functions


        


    

  
    
      
    
    
      assert_enqueued(worker_mod, filters \\ [])



        
          
        

    

  


  

      

          @spec assert_enqueued(module(), args: list(), opts: Keyword.t()) :: true


      


Assert that a job was enqueued for the given job module, optionally matching
a set of argument/option filters. By default, this assertion will fail if more
than one matching job is found. If you want to assert that multiple matching
jobs are enqueued, you can use the :count option. If you want the assertion
to pass if at least one matching job is enqueued, pass count: :any (this
should generally be discouraged in favor of a specific count, to help catch
accidental duplicate enqueues).
Examples
defmodule MyApp.Test do
  use ExUnit.Case

  import FaktoryWorker.Testing

  setup :reset_queues

  test "enqueues" do
    MyApp.Job.perform_async("argument")

    # assert that _any_ job was enqueued for this module
    assert_enqueued MyApp.Job

    # assert that a specific job was enqueued
    assert_enqueued MyApp.Job, args: ["argument"]

    # assert on multiple arguments (order matters)
    assert_enqueued MyApp.Job, args: ["foo", "bar"]

    # assert that two matching jobs were enqueued
    assert_enqueued MyApp.Job, args: ["foo", "bar"], count: 2

    # assert on serializable arguments
    assert_enqueued MyApp.Job, args: [%MyApp.User{...}]

    # assert on options (only those explicitly passed to `perform_async`)
    assert_enqueued MyApp.Job, opts: [reserve_for: 1_500]

    # assert on multiple filters
    assert_enqueued MyApp.Job, args: ["foo", "bar"], opts: [custom: %{}]
  end
end

  



  
    
      
    
    
      describe_jobs(jobs)



        
          
        

    

  


  

      

          @spec describe_jobs([FaktoryWorker.Sandbox.job()]) :: String.t()


      



  



    

    

  
    
      
    
    
      perform_job(worker_mod, arg_or_args \\ [], opts \\ [])


        (macro)


        
          
        

    

  


  

      

          @spec perform_job(module(), term() | [term()], Keyword.t()) :: Macro.t()


      


Perform the job in the same way that it will be performed when pulled
from the queue at runtime. Specifically, this means:
	work will be done in a separate process, under a Task.Supervisor
	job arguments will go through serialization/deserialization

Blocks until the job has completed, returning the result of executing
the perform function. If the job raises or exits, the return value
will be {:error, "raise or exit reason"}. If the job times out
(execution time exceeds the job's :reserve_for duration), {:error, :timeout}
will be returned instead of the normal result.
Note that ExUnit.CaptureLog, ExUnit.CaptureIO, and friends will
not work since the job process is not linked to the caller.
Examples
# arguments are optional for 0-arity jobs
perform_job(MyJob)

# single arguments may be passed directly
perform_job(MyJob, 123)

# multiple arguments in a list
perform_job(MyJob, ["foo", "bar"])

# you can pass options as well
perform_job(MyJob, ["arg1"], reserve_for: 1_500)

# if you need to pass options to a 0-arity job, you must
# pass an empty list for arguments
perform_job(MyJob, [], reserve_for: 1_500)

  



    

  
    
      
    
    
      refute_enqueued(worker_mod, filters \\ [])



        
          
        

    

  


  

      

          @spec refute_enqueued(module(), args: list(), opts: Keyword.t()) :: false


      


Assert that a job was not enqueued for the given job module, optionally
specifying a set of argument/option filters.
Examples
defmodule MyApp.Test do
  use ExUnit.Case

  import FaktoryWorker.Testing

  setup :reset_queues

  test "doesn't enqueue" do
    # refute that _any_ job was enqueued for this module
    refute_enqueued MyApp.Job

    # refute that a specific job was enqueued
    refute_enqueued MyApp.Job, args: ["argument"]

    # refute on multiple arguments (order matters)
    refute_enqueued MyApp.Job, args: ["foo", "bar"]

    # refute on serializable arguments
    refute_enqueued MyApp.Job, args: [%MyApp.User{...}]

    # refute on options (only those explicitly passed to `perform_async`)
    refute_enqueued MyApp.Job, opts: [reserve_for: 1_500]

    # refute on multiple filters
    refute_enqueued MyApp.Job, args: ["foo", "bar"], opts: [custom: %{}]
  end
end

  



    

  
    
      
    
    
      reset_queues(context \\ %{})



        
          
        

    

  


  

Resets the queue history for all job modules.
Generally, this should be called in the setup block for any tests that
use assert_enqueued/2 or refute_enqueued/2, to ensure that test cases
don't pollute each other.
This will reset the history for all job modules; if you need finer-grained
control over which job modules are reset (generally you shouldn't), use
FaktoryWorker.Sandbox.reset/1 instead.
If you don't need to perform any other setup, you can use the atom shorthand
setup :reset_queues

